[U-Boot-Users] Map output...

[Wolfgang Kanovsky]

Hi all

Can anyone help me too understand the output of the map file ....


               0x08fd702b                ali512x_set_fdc
                0x08fd7278                ali512x_set_rtc
                0x08fd74ce                __u_boot_cmd_start = .

.u_boot_cmd     0x08fd74d0      0x4c8
 *(.u_boot_cmd)
 .u_boot_cmd    0x08fd74d0       0x18 common/libcommon.a(cmd_autoscript.o)
                0x08fd74d0                __u_boot_cmd_autoscr
 .u_boot_cmd    0x08fd74e8       0x18 common/libcommon.a(cmd_bdinfo.o)
                0x08fd74e8                __u_boot_cmd_bdinfo
 .u_boot_cmd    0x08fd7500       0x30 common/libcommon.a(cmd_boot.o)
                0x08fd7518                __u_boot_cmd_reset

is from the U-Boot.map file of (sc520 board)

 0x08fd74ce                __u_boot_cmd_start = .

should point to ".u_boot_cmd     0x08fd74d0"   but it points to itself (2
Bytes Wrong! )
Why could that be ? comes this "offset" from a wrong <board>.lds file with
misalignes or wrong alinement ??


second problem :

 *fill*         0x08fdf6bc        0x4 00
 .rodata.str1.32
                0x08fdf6c0      0x20b fs/jffs2/libjffs2.a(jffs2_1pass.o)

.rel.dyn
                0x03f00000                . = 0x3f00000
                0x03f00000                _i386boot_romdata_dest = <code
335> (.)

.data           0x03f00000      0xcd0 load address 0x08fdf8cb

code335 means:
 the linker can"t find the section holding the code ..
same

              0x00000cd0                _i386boot_romdata_size = (SIZEOF
(.data) + SIZEOF (.got))
                0x03f00cd0                . = ALIGN (0x4)
                0x03f00cd0                _i386boot_bss_start = <code 335>
(.)

.bss            0x03f00ce0     0xadcc
 *(.bss)
 .bss           0x03f00ce0       0xa8 lib_i386/libi386.a(board.o)

onby i post the board.lds file maybe their is one in here who can help me
correct the file or
tell me what i made wrong ...

thanks a lot
Wolfgang K.

===================================================================
/*
 * (C) Copyright 2002
 * Daniel Engström, Omicron Ceti AB, daniel at omicron.se.
 *
 * See file CREDITS for list of people who contributed to this
 * project.
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License as
 * published by the Free Software Foundation; either version 2 of
 * the License, or (at your option) any later version.
 *
 * This program is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU General Public License for more details.
 *
 * You should have received a copy of the GNU General Public License
 * along with this program; if not, write to the Free Software
 * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
 * MA 02111-1307 USA
 */

OUTPUT_FORMAT("elf32-i386", "elf32-i386", "elf32-i386")
OUTPUT_ARCH(i386)
ENTRY(_start)

SECTIONS
{
	. = 0x8fc0000;		/* Where bootcode in the flash is mapped */
	.text  : { *(.text); }

	__u_boot_cmd_start = .;
	.u_boot_cmd : { *(.u_boot_cmd) }
	__u_boot_cmd_end = .;

        . = ALIGN(4);
        .rodata : { *(.rodata) *(.rodata.*) }

        . = 0x3f00000; 	                    /* Ram data segment to use (63Mb
lastfrom top)*/
	_i386boot_romdata_dest = ABSOLUTE(.);
        .data : AT ( LOADADDR(.rodata) + SIZEOF(.rodata) ) { *(.data) }
	_i386boot_romdata_start = LOADADDR(.data);

        . = ALIGN(4);
        .got : AT ( LOADADDR(.data) + SIZEOF(.data) ) { *(.got) }
	_i386boot_romdata_size = SIZEOF(.data) + SIZEOF(.got);


        . = ALIGN(4);
	_i386boot_bss_start = ABSOLUTE(.);
        .bss : { *(.bss) }
	_i386boot_bss_size = SIZEOF(.bss);


	/* 16bit realmode trampoline code */
	.realmode 0x7c0 : AT ( LOADADDR(.got) + SIZEOF(.got) ) { *(.realmode) }

	_i386boot_realmode = LOADADDR(.realmode);
	_i386boot_realmode_size = SIZEOF(.realmode);

	/* 16bit BIOS emulation code (just enough to boot Linux) */
	.bios 0 : AT ( LOADADDR(.realmode) + SIZEOF(.realmode) ) { *(.bios) }

	_i386boot_bios = LOADADDR(.bios);
	_i386boot_bios_size = SIZEOF(.bios);


	/* The load addresses below assumes that the flash
	 * will be mapped so that 0x8ff0000 == 0xffff0000
	 * at reset time
	 *
	 * The fe00 and ff00 offsets of the start32 and start16
	 * segments are arbitrary, the just have to be mapped
	 * at reset and the code have to fit.
	 * The fff0 offset of reset is important, however.
	 */


	. = 0xfffffe00;
	.start32 : AT (0x8fffe00) { *(.start32); }

	. = 0xff00;
	.start16 : AT (0x8ffff00) { *(.start16); }

	. = 0xfff0;
	.reset : AT (0x8fffff0) { *(.reset); }
	_i386boot_end = (LOADADDR(.reset) + SIZEOF(.reset) );
}
_