[U-Boot] [PATCH] MIPS: Add VCT board series support (Part 1/3)

[Stefan Roese]

On Monday 15 December 2008, Andrew Dyer wrote:
> On Mon, Dec 15, 2008 at 8:51 AM, Stefan Roese <sr at denx.de> wrote:
> > This patch adds support for the Micronas VCT board series.
> > Currently the following platforms are supported:
> >
> >  vct_premium

<snip>

> > +/*
> > +OUTPUT_FORMAT("elf32-bigmips", "elf32-bigmips", "elf32-bigmips")
> > +*/
> > +OUTPUT_FORMAT("elf32-tradbigmips", "elf32-tradbigmips",
> > "elf32-tradbigmips")
>
> I believe that this should be:
>
> OUTPUT_FORMAT("elf32-tradbigmips", "elf32-tradbigmips",
> "elf32-tradlittlemips")
>
> as the parameters are for default, big, little endian compilation.

I copied this from another MIPS platform (purple). So other existing ports 
will have the same problem.

I'll fix this in the next patch version.

> > +OUTPUT_ARCH(mips)
> > +ENTRY(_start)
> > +SECTIONS
> > +{
> > +       . = 0x00000000;
> > +
> > +       . = ALIGN(4);
> > +       .text       :
> > +       {
> > +         *(.text)
> > +       }
> > +
> > +       . = ALIGN(4);
> > +       .rodata  : { *(.rodata) }
> > +
> > +       . = ALIGN(4);
> > +       .data  : { *(.data) }
> > +
> > +       . = .;
> > +       _gp = ALIGN(16) + 0x7ff0;
> > +
> > +       .got : {
> > +         __got_start = .;
> > +         *(.got)
> > +         __got_end = .;
> > +       }
> > +
>
> I would force alignment here for sdata

ok.

> > +       .sdata  : { *(.sdata) }
> > +
>
> and here

ok.

> > +       .u_boot_cmd : {
> > +         __u_boot_cmd_start = .;
> > +         *(.u_boot_cmd)
> > +         __u_boot_cmd_end = .;
> > +       }
> > +
>
> uboot_end_data is assumed to be word aligned in cpu/mips/start.S,
> enforce the alignment here

ok.

> > +       uboot_end_data = .;
> > +       num_got_entries = (__got_end - __got_start) >> 2;
> > +
> > +       . = ALIGN(4);
> > +       .sbss (NOLOAD)  : { *(.sbss) }
>
> I believe .bss is also expected to be word aligned

ok.

> > +       .bss (NOLOAD)  : { *(.bss) }
> > +       uboot_end = .;
> > +}

I'll fix this in the next patch version.

Thanks.

Stefan

=====================================================================
DENX Software Engineering GmbH,     MD: Wolfgang Denk & Detlev Zundel
HRB 165235 Munich, Office: Kirchenstr.5, D-82194 Groebenzell, Germany
Phone: +49-8142-66989-0 Fax: +49-8142-66989-80  Email: office at denx.de
=====================================================================